options {
  LOOKAHEAD = 2;
  IGNORE_CASE = true;
  STATIC = false;
}


PARSER_BEGIN(EdifParserCore)

class EdifParserCore {
}

PARSER_END(EdifParserCore)


/* WHITE SPACE */

SKIP :
{
  " "
| "\t"
| "\n"
| "\r"
| "\f"
}

/* RESERVED WORDS AND LITERALS */

TOKEN :
{
< ANGLE: "ANGLE" >
| < BEHAVIOR: "BEHAVIOR" >
| < CALCULATED: "CALCULATED" >
| < CAPACITANCE: "CAPACITANCE" >
| < CENTERCENTER: "CENTERCENTER" >
| < CENTERLEFT: "CENTERLEFT" >
| < CENTERRIGHT: "CENTERRIGHT" >
| < CHARGE: "CHARGE" >
| < CONDUCTANCE: "CONDUCTANCE" >
| < CURRENT: "CURRENT" >
| < DISTANCE: "DISTANCE" >
| < DOCUMENT: "DOCUMENT" >
| < ENERGY: "ENERGY" >
| < EXTEND: "EXTEND" >
| < FLUX: "FLUX" >
| < FREQUENCY: "FREQUENCY" >
| < GENERIC: "GENERIC" >
| < GRAPHIC: "GRAPHIC" >
| < INDUCTANCE: "INDUCTANCE" >
| < INOUT: "INOUT" >
| < INPUT: "INPUT" >
| < LOGICMODEL: "LOGICMODEL" >
| < LOWERCENTER: "LOWERCENTER" >
| < LOWERLEFT: "LOWERLEFT" >
| < LOWERRIGHT: "LOWERRIGHT" >
| < MASKLAYOUT: "MASKLAYOUT" >
| < MASS: "MASS" >
| < MEASURED: "MEASURED" >
| < MX: "MX" >
| < MXR90: "MXR90" >
| < MY: "MY" >
| < MYR90: "MYR90" >
| < NETLIST: "NETLIST" >
| < OUTPUT: "OUTPUT" >
| < PCBLAYOUT: "PCBLAYOUT" >
| < POWER: "POWER" >
| < R0: "R0" >
| < R180: "R180" >
| < R270: "R270" >
| < R90: "R90" >
| < REQUIRED: "REQUIRED" >
| < RESISTANCE: "RESISTANCE" >
| < RIPPER: "RIPPER" >
| < ROUND: "ROUND" >
| < SCHEMATIC: "SCHEMATIC" >
| < STRANGER: "STRANGER" >
| < SYMBOLIC: "SYMBOLIC" >
| < TEMPERATURE: "TEMPERATURE" >
| < TIE: "TIE" >
| < TIME: "TIME" >
| < TRUNCATE: "TRUNCATE" >
| < UPPERCENTER: "UPPERCENTER" >
| < UPPERLEFT: "UPPERLEFT" >
| < UPPERRIGHT: "UPPERRIGHT" >
| < VOLTAGE: "VOLTAGE" >
| < ACLOAD: "acLoad" >
| < AFTER: "after" >
| < ANNOTATE: "annotate" >
| < APPLY: "apply" >
| < ARC: "arc" >
| < ARRAY: "array" >
| < ARRAYMACRO: "arrayMacro" >
| < ARRAYRELATEDINFO: "arrayRelatedInfo" >
| < ARRAYSITE: "arraySite" >
| < ATLEAST: "atLeast" >
| < ATMOST: "atMost" >
| < AUTHOR: "author" >
| < BASEARRAY: "baseArray" >
| < BECOMES: "becomes" >
| < BETWEEN: "between" >
| < BOOLEAN: "boolean" >
| < BOOLEANDISPLAY: "booleanDisplay" >
| < BOOLEANMAP: "booleanMap" >
| < BORDERPATTERN: "borderPattern" >
| < BORDERWIDTH: "borderWidth" >
| < BOUNDINGBOX: "boundingBox" >
| < CELL: "cell" >
| < CELLREF: "cellRef" >
| < CELLTYPE: "cellType" >
| < CHANGE: "change" >
| < CIRCLE: "circle" >
| < COLOR: "color" >
| < COMMENT: "comment" >
| < COMMENTGRAPHICS: "commentGraphics" >
| < COMPOUND: "compound" >
| < CONNECTLOCATION: "connectLocation" >
| < CONTENTS: "contents" >
| < CORNERTYPE: "cornerType" >
| < CRITICALITY: "criticality" >
| < CURRENTMAP: "currentMap" >
| < CURVE: "curve" >
| < CYCLE: "cycle" >
| < DATAORIGIN: "dataOrigin" >
| < DCFANINLOAD: "dcFaninLoad" >
| < DCFANOUTLOAD: "dcFanoutLoad" >
| < DCMAXFANIN: "dcMaxFanin" >
| < DCMAXFANOUT: "dcMaxFanout" >
| < DELAY: "delay" >
| < DELTA: "delta" >
| < DERIVATION: "derivation" >
| < DESIGN: "design" >
| < DESIGNATOR: "designator" >
| < DIFFERENCE: "difference" >
| < DIRECTION: "direction" >
| < DISPLAY: "display" >
| < DOMINATES: "dominates" >
| < DOT: "dot" >
| < DURATION: "duration" >
| < E: "e" >
| < EDIF: "edif" >
| < EDIFLEVEL: "edifLevel" >
| < EDIFVERSION: "edifVersion" >
| < ENCLOSUREDISTANCE: "enclosureDistance" >
| < ENDTYPE: "endType" >
| < ENTRY: "entry" >
| < EVENT: "event" >
| < EXACTLY: "exactly" >
| < EXTERNAL: "external" >
| < FABRICATE: "fabricate" >
| < FALSE: "false" >
| < FIGURE: "figure" >
| < FIGUREAREA: "figureArea" >
| < FIGUREGROUP: "figureGroup" >
| < FIGUREGROUPOBJECT: "figureGroupObject" >
| < FIGUREGROUPOVERRIDE: "figureGroupOverride" >
| < FIGUREGROUPREF: "figureGroupRef" >
| < FIGUREPERIMETER: "figurePerimeter" >
| < FIGUREWIDTH: "figureWidth" >
| < FILLPATTERN: "fillPattern" >
| < FOLLOW: "follow" >
| < FORBIDDENEVENT: "forbiddenEvent" >
| < GLOBALPORTREF: "globalPortref" >
| < GREATERTHAN: "greaterThan" >
| < GRIDMAP: "gridMap" >
| < IGNORE: "ignore" >
| < INCLUDEFIGUREGROUP: "includeFigureGroup" >
| < INITIAL: "initial" >
| < INSTANCE: "instance" >
| < INSTANCEBACKANNOTATE: "instanceBackAnnotate" >
| < INSTANCEGROUP: "instanceGroup" >
| < INSTANCEMAP: "instanceMap" >
| < INSTANCEREF: "instanceRef" >
| < INTEGER: "integer" >
| < INTEGERDISPLAY: "integerDisplay" >
| < INTERFACE: "interface" >
| < INTERFIGUREGROUPSPACING: "interFigureGroupSpacing" >
| < INTERSECTION: "intersection" >
| < INTRAFIGUREGROUPSPACING: "intraFigureGroupSpacing" >
| < INVERSE: "inverse" >
| < ISOLATED: "isolated" >
| < JOINED: "joined" >
| < JUSTIFY: "justify" >
| < KEYWORDDISPLAY: "keywordDisplay" >
| < KEYWORDLEVEL: "keywordLevel" >
| < KEYWORDMAP: "keywordMap" >
| < LESSTHAN: "lessThan" >
| < LIBRARY: "library" >
| < LIBRARYREF: "libraryRef" >
| < LISTOFNETS: "listofNets" >
| < LISTOFPORTS: "listOfPorts" >
| < LOADDELAY: "loadDelay" >
| < LOGICASSIGN: "logicAssign" >
| < LOGICINPUT: "logicInput" >
| < LOGICLIST: "logicList" >
| < LOGICMAPINPUT: "logicMapinput" >
| < LOGICMAPOUTPUT: "logicMapOutput" >
| < LOGICONEOF: "logicOneOf" >
| < LOGICOUTPUT: "logicOutput" >
| < LOGICPORT: "logicPort" >
| < LOGICREF: "logicRef" >
| < LOGICVALUE: "logicValue" >
| < LOGICWAVEFORM: "logicWaveform" >
| < MAINTAIN: "maintain" >
| < MATCH: "match" >
| < MEMBER: "member" >
| < MINOMAX: "miNoMax" >
| < MINOMAXDISPLAY: "miNoMaxDisplay" >
| < MNM: "mnm" >
| < MULTIPLEVALUESET: "multipleValueSet" >
| < MUSTJOIN: "mustJoin" >
| < NAME: "name" >
| < NET: "net" >
| < NETBACKANNOTATE: "netBackAnnotate" >
| < NETBUNDLE: "netBundle" >
| < NETDELAY: "netDelay" >
| < NETGROUP: "netGroup" >
| < NETMAP: "netMap" >
| < NETREF: "netRef" >
| < NOCHANGE: "noChange" >
| < NONPERMUTABLE: "nonPermutable" >
| < NOTALLOWED: "notAllowed" >
| < NOTCHSPACING: "notchSpacing" >
| < NUMBER: "number" >
| < NUMBERDEFINITION: "numberDefinition" >
| < NUMBERDISPLAY: "numberDisplay" >
| < OFFPAGECONNECTOR: "offPageConnector" >
| < OFFSETEVENT: "offsetEvent" >
| < OPENSHAPE: "openShape" >
| < ORIENTATION: "orientation" >
| < ORIGIN: "origin" >
| < OVERHANGDISTANCE: "overhangDistance" >
| < OVERLAPDISTANCE: "overlapDistance" >
| < OVERSIZE: "oversize" >
| < OWNER: "owner" >
| < PAGE: "page" >
| < PAGESIZE: "pageSize" >
| < PARAMETER: "parameter" >
| < PARAMETERASSIGN: "parameterAssign" >
| < PARAMETERDISPLAY: "parameterDisplay" >
| < PATH: "path" >
| < PATHDELAY: "pathDelay" >
| < PATHWIDTH: "pathWidth" >
| < PERMUTABLE: "permutable" >
| < PHYSICALDESIGNRULE: "physicalDesignRule" >
| < PLUG: "plug" >
| < POINT: "point" >
| < POINTDISPLAY: "pointDisplay" >
| < POINTLIST: "pointList" >
| < POLYGON: "polygon" >
| < PORT: "port" >
| < PORTBACKANNOTATE: "portBackAnnotate" >
| < PORTBUNDLE: "portBundle" >
| < PORTDELAY: "portDelay" >
| < PORTGROUP: "portGroup" >
| < PORTIMPLEMENTATION: "portImplementation" >
| < PORTINSTANCE: "portInstance" >
| < PORTLIST: "portList" >
| < PORTLISTALIAS: "portListAlias" >
| < PORTMAP: "portMap" >
| < PORTREF: "portRef" | "portref" >
| < PROGRAM: "program" >
| < PROPERTY: "property" >
| < PROPERTYDISPLAY: "propertyDisplay" >
| < PROTECTIONFRAME: "protectionFrame" >
| < PT: "pt" >
| < RANGEVECTOR: "rangeVector" >
| < RECTANGLE: "rectangle" >
| < RECTANGLESIZE: "rectangleSize" >
| < RENAME: "rename" >
| < RESOLVES: "resolves" >
| < SCALE: "scale" >
| < SCALEX: "scalex" >
| < SCALEY: "scaley" >
| < SECTION: "section" >
| < SHAPE: "shape" >
| < SIMULATE: "simulate" >
| < SIMULATIONINFO: "simulationInfo" >
| < SINGLEVALUESET: "singleValueSet" >
| < SITE: "site" >
| < SOCKET: "socket" >
| < SOCKETSET: "socketSet" >
| < STATUS: "status" >
| < STEADY: "steady" >
| < STRING: "string" >
| < STRINGDISPLAY: "stringDisplay" >
| < STRONG: "strong" >
| < SYMBOL: "symbol" >
| < SYMMETRY: "symmetry" >
| < TABLE: "table" >
| < TABLEDEFAULT: "tableDefault" >
| < TECHNOLOGY: "technology" >
| < TEXTHEIGHT: "textheight" >
| < TIMEINTERVAL: "timeinterval" >
| < TIMESTAMP: "timeStamp" >
| < TIMING: "timing" >
| < TRANSFORM: "transform" >
| < TRANSITION: "transition" >
| < TRIGGER: "trigger" >
| < TRUE: "true" >
| < UNCONSTRAINED: "unconstrained" >
| < UNDEFINED: "undefined" >
| < UNION: "union" >
| < UNIT: "unit" >
| < UNUSED: "unused" >
| < USERDATA: "userData" >
| < VERSION: "version" >
| < VIEW: "view" >
| < VIEWLIST: "viewList" >
| < VIEWMAP: "viewMap" >
| < VIEWREF: "viewRef" >
| < VIEWTYPE: "viewType" >
| < VISIBLE: "visible" >
| < VOLTAGEMAP: "voltageMap" >
| < WAVEVALUE: "waveValue" >
| < WEAK: "weak" >
| < WEAKJOINED: "weakJoined" >
| < WHEN: "when" >
| < WRITTEN: "written" >

/* level 1 reserved words */
| < ABS: "abs" >
| < AND: "and" >
| < CEILING: "ceiling" >
| < CONCAT: "concat" >
| < CONSTANT: "constant" >
| < CONSTRAINT: "constraint" >
| < DIVIDE: "divide" >
| < EQUAL: "equal" >
| < FIX: "fix" >
| < FLOOR: "floor" >
| < INCREASING: "increasing" >
| < MAX: "max" >
| < MIN: "min" >
| < MOD: "mod" >
| < NEGATE: "negate" >
| < NOT: "not" >
| < OR: "or" >
| < POINTSUBTRACT: "pointSubtract" >
| < POINTSUM: "pointSum" >
| < PRODUCT: "product" >
| < STRICTLYINCREASING: "strictlyIncreasing" >
| < SUBTRACT: "subtract" >
| < SUM: "sum" >
| < VARIABLE: "variable" >
| < XCOORD: "xCoord" >
| < XOR: "xor" >
| < YCOORD: "yCoord" >

}

/* LITERALS */

TOKEN :
{
  < INTEGER_TOK: (["-","+"])? ["0"-"9"] (["0"-"9"])* >
|
  < STRING_TOK:
      "\""
      (~["\""])*
      "\""
  >
}

/* IDENFIERS */

TOKEN :
{
  < IDENTIFIER: (<LETTER>|"&") (<LETTER>|<DIGIT>|"_")* >
|
  < #LETTER:
      [ "A"-"Z",
  	"a"-"z"]
  >
|
  < #DIGIT:
      ["0"-"9"]
  >
}

TOKEN : /* SEPARATORS */
{
  < LBR: "(" >
| < RBR: ")" >

}



/*****************************************
 * THE JAVA LANGUAGE GRAMMAR STARTS HERE *
 *****************************************/

/*
 * Program structuring syntax follows.
 */

void edif() :
{}
{
  <LBR> <EDIF> edifFileName() edifVersion() edifLevel() keywordMap() 
  ( status()  | external() | library() | design() | comment() | 
  userData() )* <RBR>
}

void edifFileName() :
{}
{
  nameDef()
}

void edifLevel() :     
{}
{
  <LBR> <EDIFLEVEL> <INTEGER_TOK> <RBR>  
}

void edifVersion() :
{}
{
  <LBR> <EDIFVERSION> <INTEGER_TOK> <INTEGER_TOK> <INTEGER_TOK> <RBR>
}

void acLoad() :        
{}
{
  <LBR> <ACLOAD> ( miNoMaxValue() | miNoMaxDisplay() ) <RBR>
}

void after() :
{}
{
  <LBR> <AFTER> miNoMaxValue() ( logicAssign() | follow() | maintain() | comment() | userData() )* <RBR>
}

void annotate() :
{}
{
  <LBR> <ANNOTATE> ( stringValue() | stringDisplay() ) <RBR>
}

void apply() :
{}
{
  <LBR> <APPLY> cycle() ( logicInput() | logicOutput() | comment() | userData() )* <RBR>
}

void arc() :
{}
{
  <LBR> <ARC> pointValue() pointValue() pointValue() <RBR>
}

void array() :
{}
{         
  <LBR> <ARRAY> nameDef() integerValue() ( integerValue() )* <RBR>
}

void arrayMacro() :
{}
{
  <LBR> <ARRAYMACRO> plug() <RBR>
}

void arrayRelatedInfo() :
{}
{
  <LBR> <ARRAYRELATEDINFO> ( arrayMacro() | arraySite() | baseArray() ) ( comment() | userData() )* <RBR>
}

void arraySite() :
{}
{
  <LBR> <ARRAYSITE> socket() <RBR>
}

void atLeast() :
{}
{
  <LBR> <ATLEAST> numberValue() <RBR>
}

void atMost() :
{}
{
  <LBR> <ATMOST> numberValue() <RBR>
}

void author() :
{}
{
  <LBR> <AUTHOR> <STRING_TOK> <RBR>
}

void baseArray() :
{}
{
  <LBR> <BASEARRAY> <RBR>
}

void becomes() :
{}
{
  <LBR> <BECOMES> ( logicNameRef() | logicList() | logicOneOf() ) <RBR>
}

void between() :
{}
{
  <LBR> <BETWEEN> ( atLeast() | greaterThan() ) ( atMost() | lessThan() ) 
  <RBR>
}

void myBoolean() :
{}
{
  <LBR> <BOOLEAN> ( booleanValue() | booleanDisplay() | myBoolean() )* <RBR>
}

void booleanDisplay() :
{}
{
  <LBR> <BOOLEANDISPLAY> booleanValue() ( display() )* <RBR>
}

void booleanMap() :
{}
{
  <LBR> <BOOLEANMAP> booleanValue() <RBR>
}

/* this function is more detailed in the level 1 edif description
void booleanValue() :
{}
{
  myFalse() | myTrue()
}
*/

void borderPattern() :
{}
{
  <LBR> <BORDERPATTERN> integerValue() integerValue() myBoolean() <RBR>
}

void borderWidth() :
{}
{
  <LBR> <BORDERWIDTH> integerValue() <RBR>
}

void boundingBox() :
{}
{
  <LBR> <BOUNDINGBOX> rectangle() <RBR>
}

void cell() :
{}
{
  <LBR> <CELL> cellNameDef() cellType() ( status() | view() | 
  viewMap() | property() | comment() | userData() )* <RBR>
}

void cellNameDef() :
{}
{
  nameDef()
}

void cellNameRef() :
{}
{
  nameRef()
}

void cellRef() :
{}
{
  <LBR> <CELLREF> cellNameRef() [ libraryRef() ] <RBR>
}

void cellType() :
{}
{
  <LBR> <CELLTYPE> ( <GENERIC> | <TIE> | <RIPPER> ) <RBR>
}

void change() :
{}
{
  <LBR> <CHANGE> ( portNameRef() | portRef() | portList() ) 
  [ transition() | becomes() ] <RBR>
}

void circle() :
{}
{
  <LBR> <CIRCLE> pointValue() pointValue() ( property() )* <RBR>
}

void color() :
{}
{
  <LBR> <COLOR> scaledInteger() scaledInteger() scaledInteger() <RBR>
}

void comment() :
{}
{
  <LBR> <COMMENT> ( <STRING_TOK> )* <RBR>
}

void commentGraphics() :
{}
{
  <LBR> <COMMENTGRAPHICS> ( annotate() | figure() | instance() | 
  boundingBox() | property() )* <RBR>
}

void compound() :
{}
{
  <LBR> <COMPOUND> ( logicNameRef() )* <RBR>
}

void connectLocation() :
{}
{
  <LBR> <CONNECTLOCATION> ( figure() )* <RBR>
}

/* this productions has a more detailed version in the level 1
void contents() :
{}
{
  <LBR> <CONTENTS> ( instance() | offPageConnector() | figure() |
  section() | net() | simulate() | when() | follow() | logicPort() | 
  boundingBox() | comment() )* <RBR>
}
*/

void cornerType() :
{}
{
  <LBR> <CORNERTYPE> ( <EXTEND> | <ROUND> | <TRUNCATE> ) <RBR>
}

void criticality() :
{}
{
  <LBR> <CRITICALITY> ( integerValue() | integerDisplay() ) <RBR>
}

void currentMap() :
{}
{
  <LBR> <CURRENTMAP> miNoMaxValue() <RBR>
}

void curve() :
{}
{
  <LBR> <CURVE> ( arc() | pointValue() )* <RBR>
}

void cycle() :
{}
{
  <LBR> <CYCLE> integerValue() [ duration() ] <RBR>
}

void dataOrigin() :
{}
{
  <LBR> <DATAORIGIN> <STRING_TOK> [ version() ] <RBR>
}

void dcFaninLoad() :
{}
{
  <LBR> <DCFANINLOAD> ( numberValue() | numberDisplay() ) <RBR>
}

void dcFanoutLoad() :
{}
{
  <LBR> <DCFANOUTLOAD> ( numberValue() | numberDisplay() ) <RBR>
}

void dcMaxFanin() :
{}
{
  <LBR> <DCMAXFANIN> ( numberValue() | numberDisplay() ) <RBR>
}

void dcMaxFanout() :
{}
{
  <LBR> <DCMAXFANOUT> ( numberValue() | numberDisplay() ) <RBR>
}

void delay() :
{}
{
  <LBR> <DELAY> ( miNoMaxValue() | miNoMaxDisplay() ) <RBR>
}

void delta() :
{}
{
  <LBR> <DELTA> ( pointValue() )* <RBR>
}

void derivation() :
{}
{
  <LBR> <DERIVATION> ( <CALCULATED> | <MEASURED> | <REQUIRED> ) <RBR>
}

void design() :
{}
{
  <LBR> <DESIGN> designNameDef() cellRef() ( status() | property() |
  comment() | userData() )* <RBR>
}

void designator() :
{}
{
  <LBR> <DESIGNATOR> ( stringValue() | stringDisplay() ) <RBR>
}

void designNameDef() :
{}
{
  nameDef()
}

void difference() :
{}
{
  <LBR> <DIFFERENCE> ( figureGroupRef() | figureOp() ) 
  ( figureGroupRef() | figureOp() )* <RBR>
}

void direction() :
{}
{
  <LBR> <DIRECTION> ( <INOUT> | <INPUT> | <OUTPUT> ) <RBR>
}

void display() :
{}
{
  <LBR> <DISPLAY> ( figureGroupNameRef() | figureGroupOverride() )
  [ justify() ] [ orientation() ] [ origin() ] <RBR>
}

void dominates() :
{}
{
  <LBR> <DOMINATES> ( logicNameRef() )* <RBR>
}

void dot() :
{}
{
  <LBR> <DOT> pointValue() ( property() )* <RBR>
}

void duration() :
{}
{
  <LBR> <DURATION> numberValue() <RBR>
}

void e() :
{}
{
  <LBR> <E> <INTEGER_TOK> <INTEGER_TOK> <RBR>
}

void enclosureDistance() :
{}
{
  <LBR> <ENCLOSUREDISTANCE> ruleNameDef() figureGroupObject()
  figureGroupObject() ( range() | singleValueSet() )
  ( comment() | userData() )* <RBR>
}

void endType() :
{}
{
  <LBR> <ENDTYPE> ( <EXTEND> | <ROUND> | <TRUNCATE> ) <RBR>
}

void entry() :
{}
{
  <LBR> <ENTRY> ( match() | change() | steady() )
  ( logicRef() | portRef() | noChange() | table() )
  [ delay() | loadDelay() ] <RBR>
}

void event() :
{}
{
  <LBR> <EVENT> ( portRef() | portList() | portGroup() | netRef() |
  netGroup() ) ( transition() | becomes() )* <RBR>
}

void exactly() :
{}
{
  <LBR> <EXACTLY> numberValue() <RBR>
}

void external() :
{}
{
  <LBR> <EXTERNAL> libraryNameDef() edifLevel() technology()
  ( status() | cell() | comment() | userData() )* <RBR>
}

void fabricate() :
{}
{
  <LBR> <FABRICATE> layerNameDef() figureGroupNameRef() <RBR>
}

void myFalse() :
{}
{
  <LBR> <FALSE> <RBR>
}

void figure() :
{}
{
  <LBR> <FIGURE> ( figureGroupNameRef() | figureGroupOverride() )
  ( circle() | dot() | openShape() | path() | polygon() | rectangle() | 
  shape() | comment() | userData() )* <RBR>
}

void figureArea() :
{}
{
  <LBR> <FIGUREAREA> ruleNameDef() figureGroupObject() 
  ( range() | singleValueSet() ) ( comment() | userData() )* <RBR>
}

void figureGroup() :
{}
{
  <LBR> <FIGUREGROUP> figureGroupNameDef() 
  ( cornerType() | endType() | pathWidth() |
  borderWidth() | color() | fillPattern()  |
  textHeight() | visible() | includeFigureGroup() |
  property() | comment() | userData() )* <RBR>
}

void figureGroupNameDef() :
{}
{
  nameDef()
}

void figureGroupNameRef() :
{}
{
  nameDef()
}

void figureGroupObject() :
{}
{
  <LBR> <FIGUREGROUPOBJECT> ( figureGroupNameRef() | figureGroupRef() | 
  figureOp() ) <RBR>
}

void figureGroupOverride() :
{}
{
  <LBR> <FIGUREGROUPOVERRIDE> figureGroupNameRef() 
  ( cornerType() | endType() | pathWidth() |
  borderWidth() | color() | fillPattern() | 
  borderPattern() | textHeight() | visible() | 
  property() | comment() | userData() )* <RBR>
}

void figureGroupRef() :
{}
{
  <LBR> <FIGUREGROUPREF> figureGroupNameRef() [ libraryRef() ] <RBR>
}

void figureOp() :
{}
{
      ( difference() | intersection() | inverse() | oversize() | union() )
}

void figurePerimeter() :
{}
{
  <LBR> <FIGUREPERIMETER> ruleNameDef() figureGroupObject() 
  ( range() | singleValueSet() ) ( comment() | userData() )* <RBR>
}

void figureWidth() :
{}
{
  <LBR> <FIGUREPERIMETER> ruleNameDef() figureGroupObject() 
  ( range() | singleValueSet() ) ( comment() | userData() )* <RBR>
}

void fillPattern() :
{}
{
  <LBR> <FILLPATTERN> integerValue() integerValue() myBoolean() <RBR>
}

void follow() :
{}
{
  <LBR> <FOLLOW> ( portNameRef() | portRef() ) ( portRef() | table() ) 
  [ delay() | loadDelay() ] <RBR>
}

void forbiddenEvent() :
{}
{
  <LBR> <FORBIDDENEVENT> timeInterval() ( event() )* <RBR>
}

void form() :
{}
{
  <LBR> keywordNameRef() ( <INTEGER_TOK> | <STRING_TOK> | ident() | form() )*
  <RBR>
}

void globalPortRef() :
{}
{
  <LBR> <GLOBALPORTREF> portNameRef() <RBR>
}

void greaterThan() :
{}
{
  <LBR> <GREATERTHAN> numberValue() <RBR>
}

void gridMap() :
{}
{
  <LBR> <GRIDMAP> numberValue() numberValue() <RBR>
}

void ignore() :
{}
{
  <LBR> <IGNORE> <RBR>
}

void includeFigureGroup() :
{}
{
  <LBR> <INCLUDEFIGUREGROUP> ( figureGroupRef() | figureOp() ) <RBR>
}

void initial() :
{}
{
  <LBR> <INITIAL> <RBR>
}

void instance() :
{}
{
  <LBR> <INSTANCE> instanceNameDef() ( viewRef() | viewList() )
  ( transform() | parameterAssign() | portInstance() |
  designator() | timing() | property() | comment() | userData() )* <RBR>
}

void instanceBackAnnotate() :
{}
{
  <LBR> <INSTANCEBACKANNOTATE> instanceRef() ( designator() | 
  timing() | property() | comment() )* <RBR>
}

void instanceGroup() :
{}
{
  <LBR> <INSTANCEGROUP> ( instanceRef() )* <RBR>
}

void instanceMap() :
{}
{
  <LBR> <INSTANCEMAP> ( instanceRef() | instanceGroup() | comment() | 
  userData() )* <RBR>
}

void instanceNameDef() :
{}
{
  nameDef() | array()
}

void instanceNameRef() :
{}
{
  nameRef() | member()
}

void instanceRef() :
{}
{
  <LBR> <INSTANCEREF> instanceNameRef() [ instanceRef() | viewRef() ] <RBR>
}

void integer() :
{}
{
  <LBR> <INTEGER> ( integerValue() | integerDisplay() | integer() )* <RBR>
}

void integerDisplay() :
{}
{
  <LBR> <INTEGERDISPLAY> integerValue() ( display() )* <RBR>
}

/* there is a more detailed production in level 1
void integerValue() :
{}
{
  <INTEGER_TOK>
}
*/

/* there is a more detailed productions in level 1
void myInterface() :
{}
{
  <LBR> <INTERFACE> ( port() | portBundle() | symbol() | 
  protectionFrame() | arrayRelatedInfo() | parameter() |
  joined() | mustJoin() | weakJoined() | permutable() | timing() |
  simulate() | designator() | property() | comment() | userData() )*
  <RBR>
}
*/

void interFigureGroupSpacing() :
{}
{
  <LBR> <INTERFIGUREGROUPSPACING> ruleNameDef() figureGroupObject()
  figureGroupObject() ( range() | singleValueSet() )
  ( comment() | userData() )* <RBR>
}

void intersection() :
{}
{
  <LBR> <INTERSECTION> ( figureGroupRef() | figureOp() ) 
  ( figureGroupRef() | figureOp() )* <RBR>
}

void intraFigureGroupSpacing() :
{}
{
  <LBR> <INTRAFIGUREGROUPSPACING> ruleNameDef() figureGroupObject()
  ( range() | singleValueSet() ) ( comment() | userData() )* <RBR>
}

void inverse() :
{}
{
  <LBR> <INVERSE> ( figureGroupRef() | figureOp() ) <RBR>
}

void isolated() :
{}
{
  <LBR> <ISOLATED> <RBR>
}

void joined() :
{}
{
  <LBR> <JOINED> ( portRef() | portList() | globalPortRef() )* <RBR>
}

void justify() :
{}
{
  <LBR> <JUSTIFY> ( <UPPERLEFT> | <UPPERCENTER> | <UPPERRIGHT> | 
  <CENTERLEFT> | <CENTERCENTER> | <CENTERRIGHT> | <LOWERLEFT> | 
  <LOWERCENTER> | <LOWERRIGHT> ) <RBR>
}

void keywordDisplay() :
{}
{
  <LBR> <KEYWORDDISPLAY> keywordNameRef() ( display() )* <RBR>
}

void keywordLevel() :
{}
{
  <LBR> <KEYWORDLEVEL> <INTEGER_TOK> <RBR>
}

void keywordMap() :
{}
{
  <LBR> <KEYWORDMAP> keywordLevel() ( comment() )* <RBR>
}

void keywordNameRef() :
{}
{
  ident()
}

void layerNameDef() :
{}
{
  nameDef()
}

void lessThan() :
{}
{
  <LBR> <LESSTHAN> numberValue() <RBR>
}

void library() :
{}
{
  <LBR> <LIBRARY> libraryNameDef() edifLevel() technology()
  ( status() | cell() | comment() | userData() )* <RBR>
}

void libraryNameDef() :
{}
{
  nameDef()
}

void libraryNameRef() :
{}
{
  nameRef()
}

void libraryRef() :
{}
{
  <LBR> <LIBRARYREF> libraryNameRef() <RBR>
}

void listOfNets() :
{}
{
  <LBR> <LISTOFNETS> ( net() )* <RBR>
}

void listOfPorts() :
{}
{
  <LBR> <LISTOFPORTS> ( port() | portBundle() )* <RBR>
}

void loadDelay() :
{}
{
  <LBR> <LOADDELAY> ( miNoMaxValue() | miNoMaxDisplay() )
  ( miNoMaxValue() | miNoMaxDisplay() ) <RBR>
}

void logicAssign() :
{}
{
  <LBR> <LOGICASSIGN> ( portNameRef() | portRef() )
  ( portRef() | logicRef() | table() )
  [ delay() | loadDelay() ] <RBR>
}

void logicInput() :
{}
{
  <LBR> <LOGICINPUT> ( portNameRef() | portRef() | portList() )
  logicWaveform() <RBR>
}

void logicList() :
{}
{
  <LBR> <LOGICLIST> ( logicNameRef() | logicOneOf() | ignore() )* <RBR>
}

void logicMapInput() :
{}
{
  <LBR> <LOGICMAPINPUT> ( logicRef() )* <RBR>
}

void logicMapOutput() :
{}
{
  <LBR> <LOGICMAPOUTPUT> ( logicRef() )* <RBR>
}

void logicNameDef() :
{}
{
  nameDef()
}

void logicNameRef() :
{}
{
  nameRef()
}

void logicOneOf() :
{}
{
  <LBR> <LOGICONEOF> ( logicNameRef() | logicList() )* <RBR>
}

void logicOutput() :
{}
{
  <LBR> <LOGICOUTPUT> ( portNameRef() | portRef() | portList() )
  logicWaveform() <RBR>
}

void logicPort() :
{}
{
  <LBR> <LOGICPORT> portNameDef() ( property() | comment() | userData() )*
  <RBR>
}

void logicRef() :
{}
{
  <LBR> <LOGICREF> logicNameRef() [ libraryRef() ] <RBR>
}

void logicValue() :
{}
{
  <LBR> <LOGICVALUE> logicNameDef() 
  ( voltageMap() | currentMap() | booleanMap() | 
  compound() | weak() | strong() | dominates() | 
  logicMapOutput() | logicMapInput() | isolated() | 
  resolves() | property() | comment() | userData() )* <RBR>
}

void logicWaveform() :
{}
{
  <LBR> <LOGICWAVEFORM> ( logicNameRef() | logicList() | logicOneOf() | 
  ignore() )* <RBR>
}

void maintain() :
{}
{
  <LBR> <MAINTAIN> ( portNameRef() | portRef() )
  [ delay() | loadDelay() ] <RBR>
}

void match() :
{}
{
  <LBR> <MATCH> ( portNameRef() | portRef() | portList() )
  ( logicNameRef() | logicList() | logicOneOf() ) <RBR>
}

void member() :
{}
{
  <LBR> <MEMBER> nameRef() integerValue() ( integerValue() )* <RBR>
}

void miNoMax() :
{}
{
  <LBR> <MINOMAX> ( miNoMaxValue() | miNoMaxDisplay() | miNoMax() )* <RBR>
}

void miNoMaxDisplay() :
{}
{
  <LBR> <MINOMAXDISPLAY> miNoMaxValue() ( display() )* <RBR>
}

/* there is a more detailed productions in level 1
void miNoMaxValue() :
{}
{
  numberValue() | mnm()
}
*/

void mnm() :
{}
{
  <LBR> <MNM> ( numberValue() | undefined() | unconstrained() )
  ( numberValue() | undefined() | unconstrained() )
  ( numberValue() | undefined() | unconstrained() ) <RBR>
}

void multipleValueSet() :
{}
{
  <LBR> <MULTIPLEVALUESET> ( rangeVector() )* <RBR>
}

void mustJoin() :
{}
{
  <LBR> <MUSTJOIN> ( portRef() | portList() | weakJoined() | joined() )* <RBR>
}

void name() :
{}
{
  <LBR> <NAME> ident() ( display() )* <RBR>
}

void nameDef() :
{}
{
  ident() | name() | rename()
}

void nameRef() :
{}
{
  ident() | name()
}

void net() :
{}
{
  <LBR> <NET> netNameDef() joined() ( criticality() | 
  netDelay() | figure() | net() | instance() | commentGraphics() |
  property() | comment() | userData() )* <RBR>
}

void netBackAnnotate() :
{}
{
  <LBR> <NETBACKANNOTATE> netRef() ( netDelay() | criticality() | 
  property() | comment() )* <RBR>
}

void netBundle() :
{}
{
  <LBR> <NETBUNDLE> netNameDef() listOfNets() ( figure() |
  commentGraphics() | property() | comment() | userData() )* <RBR>
}

void netDelay() :
{}
{
  <LBR> <NETDELAY> derivation() delay() ( transition() | becomes() )* <RBR>
}

void netGroup() :
{}
{
  <LBR> <NETGROUP> ( netNameRef() | netRef() )* <RBR>
}

void netMap() :
{}
{
  <LBR> <NETMAP> ( netRef() | netGroup() | comment() | userData() )* <RBR>
}

void netNameDef() :
{}
{
  nameDef() | array()
}

void netNameRef() :
{}
{
  nameRef() | member()
}

void netRef() :
{}
{
  <LBR> <NETREF> netNameRef() [ netRef() | instanceRef() | viewRef() ] <RBR>
}

void noChange() :
{}
{
  <LBR> <NOCHANGE> <RBR>
}

void nonPermutable() :
{}
{
  <LBR> <NONPERMUTABLE> ( portRef() | permutable() )* <RBR>
}

void notAllowed() :
{}
{
  <LBR> <NOTALLOWED> ruleNameDef() figureGroupObject() ( comment() |
  userData() )* <RBR>
}

void notchSpacing() :
{}
{
  <LBR> <NOTCHSPACING> ruleNameDef() figureGroupObject() 
  ( range() | singleValueSet() ) ( comment() | userData() )* <RBR>
}

void number() :
{}
{
  <LBR> <NUMBER> ( numberValue() | numberDisplay() | number() )* <RBR>
}

void numberDefinition() :
{}
{
  <LBR> <NUMBERDEFINITION> ( scale() | gridMap() | comment() )* <RBR>
}

void numberDisplay() :
{}
{
  <LBR> <NUMBERDISPLAY> numberValue() ( display() )* <RBR>
}

/* there is a more detailed productions in level 1
void numberValue() :
{}
{
  scaledInteger()
}
*/

void offPageConnector() :
{}
{
  <LBR> <OFFPAGECONNECTOR> portNameDef() ( unused() | property() |
  comment() | userData() )* <RBR>
}

void offsetEvent() :
{}
{
  <LBR> <OFFSETEVENT> event() numberValue() <RBR>
}

void openShape() :
{}
{
  <LBR> <OPENSHAPE> curve() ( property() )* <RBR>
}

void orientation() :
{}
{
  <LBR> <ORIENTATION> ( <R0> | <R90> | <R180> | <R270> | <MX> | 
  <MY> | <MYR90> | <MXR90> ) <RBR>
}

void origin() :
{}
{
  <LBR> <ORIGIN> pointValue() <RBR>
}

void overhangDistance() :
{}
{
  <LBR> <OVERHANGDISTANCE> ruleNameDef() figureGroupObject() 
  figureGroupObject() ( range() | singleValueSet() )
  ( comment() | userData() )* <RBR>
}

void overlapDistance() :
{}
{
  <LBR> <OVERLAPDISTANCE> ruleNameDef() figureGroupObject()
  figureGroupObject() ( range() | singleValueSet() )
  ( comment() | userData() )* <RBR>
}

void oversize() :
{}
{
  <LBR> <OVERSIZE> integerValue() ( figureGroupRef() | figureOp() )
  cornerType() <RBR>
}

void owner() :
{}
{
  <LBR> <OWNER> <STRING_TOK> <RBR>
}

/* there is a more detailed productions in level 1
void page() :
{}
{
  <LBR> <PAGE> instanceNameDef() ( instance() | net() | netBundle() | 
  commentGraphics() | portImplementation() | pageSize() | 
  boundingBox() | comment() | userData() )* <RBR>
}
*/

void pageSize() :
{}
{
  <LBR> <PAGESIZE> rectangle() <RBR>
}

void parameter() :
{}
{
  <LBR> <PARAMETER> valueNameDef() typedValue() [ unit() ] <RBR>
}

void parameterAssign() :
{}
{
  <LBR> <PARAMETERASSIGN> valueNameRef() typedValue() <RBR>
}

void parameterDisplay() :
{}
{
  <LBR> <PARAMETERDISPLAY> valueNameRef() ( display() )* <RBR>
}

void path() :
{}
{
  <LBR> <PATH> pointList() ( property() )* <RBR>
}

void pathDelay() :
{}
{
  <LBR> <PATHDELAY> delay() ( event() )* <RBR>
}

void pathWidth() :
{}
{
  <LBR> <PATHWIDTH> integerValue() <RBR>
}

void permutable() :
{}
{
  <LBR> <PERMUTABLE> ( portRef() | permutable() | nonPermutable() )* <RBR>
}

void physicalDesignRule() :
{}
{
  <LBR> <PHYSICALDESIGNRULE> ( figureWidth() | figureArea() |
  rectangleSize() | figurePerimeter() | overlapDistance() | 
  overhangDistance() | enclosureDistance() | interFigureGroupSpacing() |
  intraFigureGroupSpacing() | notchSpacing() | notAllowed() | 
  figureGroup() | comment() | userData() )* <RBR>
}

void plug() :
{}
{
  <LBR> <PLUG> ( socketSet() )* <RBR>
}

void point() :
{}
{
  <LBR> <POINT> ( pointValue() | pointDisplay() | point() )* <RBR>
}

void pointDisplay() :
{}
{
  <LBR> <POINTDISPLAY> pointValue() ( display() )* <RBR>
}

void pointList() :
{}
{
  <LBR> <POINTLIST> ( pointValue() )* <RBR>
}

/* there is a more detailed productions in level 1
void pointValue() :
{}
{
  pt()
}
*/

void polygon() :
{}
{
  <LBR> <POLYGON> pointList() ( property() )* <RBR>
}

void port() :
{}
{
  <LBR> <PORT> portNameDef() ( direction() | unused() | 
  designator() | dcFaninLoad() | dcFanoutLoad() | 
  dcMaxFanin() | acLoad() | portDelay() | property() |
  comment() | userData() )* <RBR>
}

void portBackAnnotate() :
{}
{
  <LBR> <PORTBACKANNOTATE> portRef() ( designator() | 
  dcFaninLoad() | dcFanoutLoad() | dcMaxFanin() | 
  dcMaxFanout() | acLoad() | portDelay() |
  property() | comment() )* <RBR>
}

void portBundle() :
{}
{
  <LBR> <PORTBUNDLE> portNameDef() listOfPorts() ( property() | comment() |
  userData() )* <RBR>
}

void portDelay() :
{}
{
  <LBR> <PORTDELAY> derivation() ( delay() | loadDelay() ) 
  ( transition() | becomes() )* <RBR>
}

void portGroup() :
{}
{
  <LBR> <PORTGROUP> ( portNameRef() | portRef() )* <RBR>
}

void portImplementation() :
{}
{
  <LBR> <PORTIMPLEMENTATION> ( portNameRef() | portRef() )
  ( connectLocation() | figure() | instance() | commentGraphics() |
  propertyDisplay() | keywordDisplay() | property() | comment() |
  userData() )* <RBR>
}

void portInstance() :
{}
{
  <LBR> <PORTINSTANCE> ( portNameRef() | portRef() )
  ( unused() | designator() | dcFaninLoad() | 
  dcFanoutLoad() | dcMaxFanin() | acLoad() | 
  portDelay() | property() | comment() | userData() )* <RBR>
}

void portList() :
{}
{
  <LBR> <PORTLIST> ( portNameRef() | portRef() )* <RBR>
}

void portListAlias() :
{}
{
  <LBR> <PORTLISTALIAS> portNameDef() portList() <RBR>
}

void portMap() :
{}
{
  <LBR> <PORTMAP> ( portRef() | portGroup() | comment() | userData() )* <RBR>
}

void portNameDef() :
{}
{
  nameDef() | array()
}

void portNameRef() :
{}
{
  nameRef() | member()
}

void portRef() :
{}
{
  <LBR> <PORTREF> portNameRef() [ portRef() | instanceRef() | viewRef() ] 
  <RBR>
}

void program() :
{}
{
  <LBR> <PROGRAM> <STRING_TOK> [ version() ] <RBR>
}

void property() :
{}
{
  <LBR> <PROPERTY> propertyNameDef() typedValue() ( owner() | 
  unit() | property() | comment() )* <RBR>
}

void propertyDisplay() :
{}
{
  <LBR> <PROPERTYDISPLAY> propertyNameRef() ( display() )* <RBR>
}

void propertyNameDef() :
{}
{
  nameDef()
}

void propertyNameRef() :
{}
{
  nameRef()
}

void protectionFrame() :
{}
{
  <LBR> <PROTECTIONFRAME> ( portImplementation() | figure() | instance() |
  commentGraphics() | boundingBox() | propertyDisplay() |
  keywordDisplay() | parameterDisplay() | property() | comment() | 
  userData() )* <RBR>
}

void pt() :
{}
{
  <LBR> <PT> integerValue() integerValue() <RBR>
}

void range() :
{}
{
  atLeast() | atMost() | between() | exactly() | greaterThan() | lessThan()
}

void rangeVector() :
{}
{
  <LBR> <RANGEVECTOR> ( range() | singleValueSet() )* <RBR>
}

void rectangle() :
{}
{
  <LBR> <RECTANGLE> pointValue() pointValue() ( property() )* <RBR>
}

void rectangleSize() :
{}
{
  <LBR> <RECTANGLESIZE> ruleNameDef() figureGroupObject()
  ( rangeVector() | multipleValueSet() )
  ( comment() | userData() )* <RBR>
}

void rename() :
{}
{
  <LBR> <RENAME> ( ident() | name() ) 
  ( <STRING_TOK> | stringDisplay() ) <RBR>
}

void resolves() :
{}
{
  <LBR> <RESOLVES> ( logicNameRef() )* <RBR>
}

void ruleNameDef() :
{}
{
  nameDef()
}

void scale() :
{}
{
  <LBR> <SCALE> numberValue() numberValue() unit() <RBR>
}

void scaledInteger() :
{}
{
  <INTEGER_TOK> | e()
}

void scaleX() :
{}
{
  <LBR> <SCALEX> integerValue() integerValue() <RBR>
}

void scaleY() :
{}
{
  <LBR> <SCALEY> integerValue() integerValue() <RBR>
}

void section() :
{}
{
  <LBR> <SECTION> stringValue() ( stringValue() | section() | instance() )*
  <RBR>
}

void shape() :
{}
{
  <LBR> <SHAPE> curve() ( property() )* <RBR>
}

void simulate() :
{}
{
  <LBR> <SIMULATE> simulateNameDef() ( portListAlias() | waveValue() |
  apply() | comment() | userData() )* <RBR>
}

void simulateNameDef() :
{}
{
  nameDef()
}

void simulationInfo() :
{}
{
  <LBR> <SIMULATIONINFO> ( logicValue() | comment() | userData() )* <RBR>
}

void singleValueSet() :
{}
{
  <LBR> <SINGLEVALUESET> ( range() )* <RBR>
}

void site() :
{}
{
  <LBR> <SITE> viewRef() [ transform() ] <RBR>
}

void socket() :
{}
{
  <LBR> <SOCKET> [ symmetry() ] <RBR>
}

void socketSet() :
{}
{
  <LBR> <SOCKETSET> symmetry() ( site() )* <RBR>
}

void status() :
{}
{
  <LBR> <STATUS> ( written() | comment() | userData() )* <RBR>
}

void steady() :
{}
{
  <LBR> <STEADY> ( portNameRef() | portRef() | portList() ) duration()
  [ transition() | becomes() ] <RBR>
}

void string() :
{}
{
  <LBR> <STRING> ( stringValue() | stringDisplay() | string() )* <RBR>
}

void stringDisplay() :
{}
{
  <LBR> <STRINGDISPLAY> stringValue() ( display() )* <RBR>
}

/* there is a more detailed productions in level 1
void stringValue() :
{}
{
  <STRING_TOK>
}
*/

void strong() :
{}
{
  <LBR> <STRONG> logicNameRef() <RBR>
}

void symbol() :
{}
{
  <LBR> <SYMBOL> ( portImplementation() | figure() | annotate() |
  instance() | commentGraphics() | pageSize() | boundingBox() | 
  propertyDisplay() | keywordDisplay() | parameterDisplay() | property() |
  comment() | userData() )* <RBR>
}

void symmetry() :
{}
{
  <LBR> <SYMMETRY> ( transform() )* <RBR>
}

void table() :
{}
{
  <LBR> <TABLE> ( entry() | tableDefault() )* <RBR>
}

void tableDefault() :
{}
{
  <LBR> <TABLEDEFAULT> ( logicRef() | portRef() | noChange() | table() )
  [ delay() | loadDelay() ] <RBR>
}

/* there is a more detailed productions in level 1
void technology() :
{}
{
  <LBR> <TECHNOLOGY> numberDefinition() ( figureGroup() | fabricate() |
  simulationInfo() | physicalDesignRule() | comment() |
  userData() )* <RBR>
}
*/

void textHeight() :
{}
{
  <LBR> <TEXTHEIGHT> integerValue() <RBR>
}

void timeInterval() :
{}
{
  <LBR> <TIMEINTERVAL> ( event() | offsetEvent() ) ( event() |
  offsetEvent() | duration() ) <RBR>
}

void timeStamp() :
{}
{
  <LBR> <TIMESTAMP> <INTEGER_TOK> <INTEGER_TOK> <INTEGER_TOK>
  <INTEGER_TOK> <INTEGER_TOK> <INTEGER_TOK> <RBR>
}

void timing() :
{}
{
  <LBR> <TIMING> derivation() ( pathDelay() | forbiddenEvent() |
  comment() | userData() )* <RBR>
}

void transform() :
{}
{
  <LBR> <TRANSFORM> [ scaleX() ] [ scaleY() ] [ delta() ] 
  [ orientation() ] [ origin() ] <RBR>
}

void transition() :
{}
{
  <LBR> <TRANSITION> ( logicNameRef() | logicList() | logicOneOf() )
  ( logicNameRef() | logicList() | logicOneOf() ) <RBR>
}

void trigger() :
{}
{
  <LBR> <TRIGGER> ( change() | steady() | initial() )* <RBR>
}

void myTrue() :
{}
{
  <LBR> <TRUE> <RBR>
}

void typedValue() :
{}
{
  myBoolean() | integer() | miNoMax() | number() | point() | string()
}

void unconstrained() :
{}
{
  <LBR> <UNCONSTRAINED> <RBR>
}

void undefined() :
{}
{
  <LBR> <UNDEFINED> <RBR>
}

void union() :
{}
{
  <LBR> <UNION> ( figureGroupRef() | figureOp() ) 
  ( figureGroupRef() | figureOp() )* <RBR>
}

void unit() :
{}
{
  <LBR> <UNIT> ( <ANGLE> | <CAPACITANCE> | <CONDUCTANCE> | <CHARGE> | 
  <CURRENT> | <DISTANCE> | <ENERGY> | <FLUX> | <FREQUENCY> | 
  <INDUCTANCE> | <MASS> | <POWER> | <RESISTANCE> | <TEMPERATURE> | 
  <TIME> | <VOLTAGE> ) <RBR>
}

void unused() :
{}
{
  <LBR> <UNUSED> <RBR>
}

void userData() :
{}
{
  <LBR> <USERDATA> ident() ( <INTEGER_TOK> | <STRING_TOK> |
  ident() | form() | string() | owner() | property() )* <RBR>
}

void valueNameDef() :
{}
{
  nameDef() | array()
}

void valueNameRef() :
{}
{
  nameRef() | member()
}

void version() :
{}
{
  <LBR> <VERSION> <STRING_TOK> <RBR>
}

void view() :
{}
{
  <LBR> <VIEW> viewNameDef() viewType() myInterface() ( status() | 
  contents() | comment() | property() | userData() )* <RBR>
}

void viewList() :
{}
{
  <LBR> <VIEWLIST> ( viewRef() | viewList() )* <RBR>
}

void viewMap() :
{}
{
  <LBR> <VIEWMAP> ( portMap() | portBackAnnotate() | instanceMap() |
  instanceBackAnnotate() | netMap() | netBackAnnotate() | comment() |
  userData() )* <RBR>
}

void viewNameDef() :
{}
{
  nameDef()
}

void viewNameRef() :
{}
{
  nameRef()
}

void viewRef() :
{}
{
  <LBR> <VIEWREF> viewNameRef() [ cellRef() ] <RBR>
}

void viewType() :
{}
{
  <LBR> <VIEWTYPE> ( <BEHAVIOR> | <DOCUMENT> | <GRAPHIC> | <LOGICMODEL> | 
  <MASKLAYOUT> | <NETLIST> | <PCBLAYOUT> | <SCHEMATIC> | <STRANGER> | 
  <SYMBOLIC> ) <RBR>
}

void visible() :
{}
{
  <LBR> <VISIBLE> booleanValue() <RBR>
}

void voltageMap() :
{}
{
  <LBR> <VOLTAGEMAP> miNoMaxValue() <RBR>
}

void waveValue() :
{}
{
  <LBR> <WAVEVALUE> logicNameDef() numberValue() logicWaveform() <RBR>
}

void weak() :
{}
{
  <LBR> <WEAK> logicNameRef() <RBR>
}

void weakJoined() :
{}
{
  <LBR> <WEAKJOINED> ( portRef() | portList() | joined() )* <RBR>
}

void when() :
{}
{
  <LBR> <WHEN> trigger() ( after() | follow() | logicAssign() | maintain() |
  comment() | userData() )* <RBR>
}

void written() :
{}
{
  <LBR> <WRITTEN> timeStamp() ( author() | program() | 
  dataOrigin() | property() | comment() | userData() )* <RBR>
}

/* Level 1 productions */

void abs() :
{}
{
  "(" "abs" numberValue() ")"
}

void and() :
{}
{
  "(" "and" ( booleanValue() )* ")"
}

void booleanValue() :
{}
{
  myFalse() | myTrue() | valueNameRef() | and() | or() | not() | xor() | equal() |
  increasing() | strictlyIncreasing()
}

void ceiling() :
{}
{
  "(" "ceiling" numberValue() ")"
}

void concat() :
{}
{
  "(" "concat" ( stringValue() )* ")"
}

void constant() :
{}
{
  "(" "constant" valueNameDef() typedValue() ")"
}

void constraint() :
{}
{
  "(" "constraint" booleanValue() ( property() )* ")"
}

void contents() :
{}
{
  "(" "contents" ( instance() | offPageConnector() | figure() | section() | net() |
  netBundle() | page() | commentGraphics() | portImplementation() | timing() | 
  simulate() | when() | follow() | logicPort() | boundingBox() |
  constant() | constraint() | variable() | comment() | userData() )* ")"
}

void divide() :
{}
{
  "(" "divide" numberValue() ( numberValue() )* ")"
}

void equal() :
{}
{
  "(" "equal" numberValue() | ( numberValue() )* ")"
}

void fix() :
{}
{
  "(" "fix" numberValue() ")"
}

void floor() :
{}
{
  "(" "floor" numberValue() ")"
}

void ident() :
{}
{
  <IDENTIFIER> | <SUM> | <ANGLE> | <BEHAVIOR> | <CALCULATED> | <CAPACITANCE> | <CENTERCENTER> | <CENTERLEFT> | <CENTERRIGHT> | <CHARGE> | <CONDUCTANCE> | <CURRENT> | <DISTANCE> | <DOCUMENT> | <ENERGY> | <EXTEND> | <FLUX> | <FREQUENCY> | <GENERIC> | <GRAPHIC> | <INDUCTANCE> | <INOUT> | <INPUT> | <LOGICMODEL> | <LOWERCENTER> | <LOWERLEFT> | <LOWERRIGHT> | <MASKLAYOUT> | <MASS> | <MEASURED> | <MX> | <MXR90> | <MY> | <MYR90> | <NETLIST> | <OUTPUT> | <PCBLAYOUT> | <POWER> | <R0> | <R180> | <R270> | <R90> | <REQUIRED> | <RESISTANCE> | <RIPPER> | <ROUND> | <SCHEMATIC> | <STRANGER> | <SYMBOLIC> | <TEMPERATURE> | <TIE> | <TIME> | <TRUNCATE> | <UPPERCENTER> | <UPPERLEFT> | <UPPERRIGHT> | <VOLTAGE> | <ACLOAD> | <AFTER> | <ANNOTATE> | <APPLY> | <ARC> | <ARRAY> | <ARRAYMACRO> | <ARRAYRELATEDINFO> | <ARRAYSITE> | <ATLEAST> | <ATMOST> | <AUTHOR> | <BASEARRAY> | <BECOMES> | <BETWEEN> | <BOOLEAN> | <BOOLEANDISPLAY> | <BOOLEANMAP> | <BORDERPATTERN> | <BORDERWIDTH> | <BOUNDINGBOX> | <CELL> | <CELLREF> | <CELLTYPE> | <CHANGE> | <CIRCLE> | <COLOR> | <COMMENT> | <COMMENTGRAPHICS> | <COMPOUND> | <CONNECTLOCATION> | <CONTENTS> | <CORNERTYPE> | <CRITICALITY> | <CURRENTMAP> | <CURVE> | <CYCLE> | <DATAORIGIN> | <DCFANINLOAD> | <DCFANOUTLOAD> | <DCMAXFANIN> | <DCMAXFANOUT> | <DELAY> | <DELTA> | <DERIVATION> | <DESIGN> | <DESIGNATOR> | <DIFFERENCE> | <DIRECTION> | <DISPLAY> | <DOMINATES> | <DOT> | <DURATION> | <E> | <EDIF> | <EDIFLEVEL> | <EDIFVERSION> | <ENCLOSUREDISTANCE> | <ENDTYPE> | <ENTRY> | <EVENT> | <EXACTLY> | <EXTERNAL> | <FABRICATE> | <FALSE> | <FIGURE> | <FIGUREAREA> | <FIGUREGROUP> | <FIGUREGROUPOBJECT> | <FIGUREGROUPOVERRIDE> | <FIGUREGROUPREF> | <FIGUREPERIMETER> | <FIGUREWIDTH> | <FILLPATTERN> | <FOLLOW> | <FORBIDDENEVENT> | <GLOBALPORTREF> | <GREATERTHAN> | <GRIDMAP> | <IGNORE> | <INCLUDEFIGUREGROUP> | <INITIAL> | <INSTANCE> | <INSTANCEBACKANNOTATE> | <INSTANCEGROUP> | <INSTANCEMAP> | <INSTANCEREF> | <INTEGER> | <INTEGERDISPLAY> | <INTERFACE> | <INTERFIGUREGROUPSPACING> | <INTERSECTION> | <INTRAFIGUREGROUPSPACING> | <INVERSE> | <ISOLATED> | <JOINED> | <JUSTIFY> | <KEYWORDDISPLAY> | <KEYWORDLEVEL> | <KEYWORDMAP> | <LESSTHAN> | <LIBRARY> | <LIBRARYREF> | <LISTOFNETS> | <LISTOFPORTS> | <LOADDELAY> | <LOGICASSIGN> | <LOGICINPUT> | <LOGICLIST> | <LOGICMAPINPUT> | <LOGICMAPOUTPUT> | <LOGICONEOF> | <LOGICOUTPUT> | <LOGICPORT> | <LOGICREF> | <LOGICVALUE> | <LOGICWAVEFORM> | <MAINTAIN> | <MATCH> | <MEMBER> | <MINOMAX> | <MINOMAXDISPLAY> | <MNM> | <MULTIPLEVALUESET> | <MUSTJOIN> | <NAME> | <NET> | <NETBACKANNOTATE> | <NETBUNDLE> | <NETDELAY> | <NETGROUP> | <NETMAP> | <NETREF> | <NOCHANGE> | <NONPERMUTABLE> | <NOTALLOWED> | <NOTCHSPACING> | <NUMBER> | <NUMBERDEFINITION> | <NUMBERDISPLAY> | <OFFPAGECONNECTOR> | <OFFSETEVENT> | <OPENSHAPE> | <ORIENTATION> | <ORIGIN> | <OVERHANGDISTANCE> | <OVERLAPDISTANCE> | <OVERSIZE> | <OWNER> | <PAGE> | <PAGESIZE> | <PARAMETER> | <PARAMETERASSIGN> | <PARAMETERDISPLAY> | <PATH> | <PATHDELAY> | <PATHWIDTH> | <PERMUTABLE> | <PHYSICALDESIGNRULE> | <PLUG> | <POINT> | <POINTDISPLAY> | <POINTLIST> | <POLYGON> | <PORT> | <PORTBACKANNOTATE> | <PORTBUNDLE> | <PORTDELAY> | <PORTGROUP> | <PORTIMPLEMENTATION> | <PORTINSTANCE> | <PORTLIST> | <PORTLISTALIAS> | <PORTMAP> | <PORTREF> | <PROGRAM> | <PROPERTY> | <PROPERTYDISPLAY> | <PROTECTIONFRAME> | <PT> | <RANGEVECTOR> | <RECTANGLE> | <RECTANGLESIZE> | <RENAME> | <RESOLVES> | <SCALE> | <SCALEX> | <SCALEY> | <SECTION> | <SHAPE> | <SIMULATE> | <SIMULATIONINFO> | <SINGLEVALUESET> | <SITE> | <SOCKET> | <SOCKETSET> | <STATUS> | <STEADY> | <STRING> | <STRINGDISPLAY> | <STRONG> | <SYMBOL> | <SYMMETRY> | <TABLE> | <TABLEDEFAULT> | <TECHNOLOGY> | <TEXTHEIGHT> | <TIMEINTERVAL> | <TIMESTAMP> | <TIMING> | <TRANSFORM> | <TRANSITION> | <TRIGGER> | <TRUE> | <UNCONSTRAINED> | <UNDEFINED> | <UNION> | <UNIT> | <UNUSED> | <USERDATA> | <VERSION> | <VIEW> | <VIEWLIST> | <VIEWMAP> | <VIEWREF> | <VIEWTYPE> | <VISIBLE> | <VOLTAGEMAP> | <WAVEVALUE> | <WEAK> | <WEAKJOINED> | <WHEN> | <WRITTEN> | <ABS> | <AND> | <CEILING> | <CONCAT> | <CONSTANT> | <CONSTRAINT> | <DIVIDE> | <EQUAL> | <FIX> | <FLOOR> | <INCREASING> | <MAX> | <MIN> | <MOD> | <NEGATE> | <NOT> | <OR> | <POINTSUBTRACT> | <POINTSUM> | <PRODUCT> | <STRICTLYINCREASING> | <SUBTRACT> | <SUM> | <VARIABLE> | <XCOORD> | <XOR> | <YCOORD>
}

void increasing() :
{}
{
  "(" "increasing" numberValue() ( numberValue() )* ")"
}

void integerValue() :
{}
{
  <INTEGER_TOK> | valueNameRef() | floor() | ceiling() | fix() |
  mod() | xCoord() | yCoord() | abs() | max() | min() | negate() |
  product() | subtract() | sum()
}

void myInterface() :
{}
{
  "(" "interface" ( port() | portBundle() | symbol() | protectionFrame() |
  arrayRelatedInfo() | parameter() | joined() | mustJoin() |
  weakJoined() | permutable() | timing() | simulate() | designator() |
  constant() | constraint() | variable() | property() | comment() | userData() )* ")"
}

void max() :
{}
{
  "(" "max" numberValue() ( numberValue() )* ")"
}

void min() :
{}
{
  "(" "min" numberValue() ( numberValue() )* ")"
}

void miNoMaxValue() :
{}
{
  numberValue() | mnm()
}

void mod() :
{}
{
  "(" "mod" integerValue() integerValue() ")"
}

void negate() :
{}
{
  "(" "negate" numberValue() ")"
}

void not() :
{}
{
  "(" "not" booleanValue() ")"
}

void numberValue() :
{}
{
  scaledInteger() | valueNameRef() | floor() | ceiling() | fix() |
  mod() | xCoord() | yCoord() | abs() | max() | min() | negate() |
  product() | subtract() | sum()
}

void or() :
{}
{
  "(" "or" ( booleanValue() )* ")"
}

void page() :
{}
{
  "(" "page" instanceNameDef() ( instance() | net() | netBundle() | commentGraphics() | 
  portImplementation() | pageSize() | boundingBox() | constant() | constraint() |
  variable() | comment() | userData() )* ")"
}

void pointSubtract() :
{}
{
  "(" "pointSubtract" pointValue() ( pointValue() )* ")"
}

void pointSum() :
{}
{
  "(" "pointSum" ( pointValue() )* ")"
}

void pointValue() :
{}
{
  pt() | valueNameRef() | pointSum() | pointSubtract()
}

void product() :
{}
{
  "(" "product" ( numberValue() )* ")"
}

void strictlyIncreasing() :
{}
{
  "(" "strictlyIncreasing" numberValue() ( numberValue() )* ")"
}

void stringValue() :
{}
{
  <STRING_TOK> | valueNameRef() | concat()
}

void subtract() :
{}
{
  "(" "subtract" numberValue() ( numberValue() )* ")"
}

void sum() :
{}
{
  "(" "sum" ( numberValue() )* ")"
}

void technology() :
{}
{
  "(" "technology" numberDefinition() ( figureGroup() | fabricate() | simulationInfo() |
  physicalDesignRule() | constant() | constraint() | comment() | userData() )* ")"
}

void variable() :
{}
{
  "(" "variable" valueNameDef() typedValue() ")"
}

void xCoord() :
{}
{
  "(" "xCoord" pointValue() ")"
}

void xor() :
{}
{
  "(" "xor" ( booleanValue() )* ")"
}

void yCoord() :
{}
{
  "(" "yCoord" pointValue() ")"
}